Changing U-boot relocation addres for T-series, T1042

cancel
Showing results for 
Show  only  | Search instead for 
Did you mean: 

Changing U-boot relocation addres for T-series, T1042

Jump to solution
1,212 Views
yusufalti333
Contributor IV

Hello,

I want to modify U-boot to relocate itself to on-board SRAM of chip (T1042) instead of DRAM.

At first, there is call list in u-boot/common/board_f.c and it has a line to call dram_init. I will change this line with my custom sram_init function.

Capture.PNG

The function board_f() is being called in start.S which is located at u-boot/arch/powerpc/cpu/mpc85xx/ 

start.S file also includes a region to relocate itself by changing Link Register. Code region is:

/*
* void relocate_code(addr_sp, gd, addr_moni)
*
* This "function" does not return, instead it continues in RAM
* after relocating the monitor code.
*
* r3 = dest
* r4 = src
* r5 = length in bytes
* r6 = cachelinesize
*/
.globl relocate_code
relocate_code:
mr r1,r3 /* Set new stack pointer */
mr r9,r4 /* Save copy of Init Data pointer */
mr r10,r5 /* Save copy of Destination Address */

GET_GOT
#ifndef CONFIG_SPL_SKIP_RELOCATE
mr r3,r5 /* Destination Address */
lis r4,CONFIG_SYS_MONITOR_BASE@h /* Source Address */
ori r4,r4,CONFIG_SYS_MONITOR_BASE@l
lwz r5,GOT(__init_end)
sub r5,r5,r4
li r6,CONFIG_SYS_CACHELINE_SIZE /* Cache Line Size */

/*
* Fix GOT pointer:
*
* New GOT-PTR = (old GOT-PTR - CONFIG_SYS_MONITOR_BASE) + Destination Address
*
* Offset:
*/
sub r15,r10,r4

/* First our own GOT */
add r12,r12,r15
/* the the one used by the C code */
add r30,r30,r15

/*
* Now relocate code
*/

cmplw cr1,r3,r4
addi r0,r5,3
srwi. r0,r0,2
beq cr1,4f /* In place copy is not necessary */
beq 7f /* Protect against 0 count */
mtctr r0
bge cr1,2f

la r8,-4(r4)
la r7,-4(r3)
1: lwzu r0,4(r8)
stwu r0,4(r7)
bdnz 1b
b 4f

2: slwi r0,r0,2
add r8,r4,r0
add r7,r3,r0
3: lwzu r0,-4(r8)
stwu r0,-4(r7)
bdnz 3b

/*
* Now flush the cache: note that we must start from a cache aligned
* address. Otherwise we might miss one cache line.
*/
4: cmpwi r6,0
add r5,r3,r5
beq 7f /* Always flush prefetch queue in any case */
subi r0,r6,1
andc r3,r3,r0
mr r4,r3
5: dcbst 0,r4
add r4,r4,r6
cmplw r4,r5
blt 5b
sync /* Wait for all dcbst to complete on bus */
mr r4,r3
6: icbi 0,r4
add r4,r4,r6
cmplw r4,r5
blt 6b
7: sync /* Wait for all icbi to complete on bus */
isync

/*
* We are done. Do not return, instead branch to second part of board
* initialization, now running from RAM.
*/

addi r0,r10,in_ram - _start

/*
* As IVPR is going to point RAM address,
* Make sure IVOR15 has valid opcode to support debugger
*/
mtspr IVOR15,r0

/*
* Re-point the IVPR at RAM
*/
mtspr IVPR,r10

mtlr r0
blr /* NEVER RETURNS! */
#endif

 

My question is, in above code, how relocate_code() function is calculating the jump address of Link Register. What should be done to change it to point SRAM of t1042 after we initialize it in board_init_f() function. ?

 

Thanks.

 

0 Kudos
1 Solution
1,186 Views
yipingwang
NXP TechSupport
NXP TechSupport

Please modify CONFIG_SYS_MONITOR_BASE configuration in include/configs/T104xRDB.h. Image has been relocated to CONFIG_SYS_MONITOR_BASE on the second stage.

CONFIG_SYS_MONITOR_BASE:
Physical start address of boot monitor code (set by make config files to be same as the text base address (CONFIG_SYS_TEXT_BASE) used when linking) - same as CONFIG_SYS_FLASH_BASE when booting from flash.

View solution in original post

0 Kudos
1 Reply
1,187 Views
yipingwang
NXP TechSupport
NXP TechSupport

Please modify CONFIG_SYS_MONITOR_BASE configuration in include/configs/T104xRDB.h. Image has been relocated to CONFIG_SYS_MONITOR_BASE on the second stage.

CONFIG_SYS_MONITOR_BASE:
Physical start address of boot monitor code (set by make config files to be same as the text base address (CONFIG_SYS_TEXT_BASE) used when linking) - same as CONFIG_SYS_FLASH_BASE when booting from flash.

0 Kudos