topic Re: Padding FLASH without overflowing memory in Kinetis Design Studio

Padding FLASH without overflowing memory

robertpoor — Thu, 09 Aug 2018 00:28:51 GMT

I'm using a flash-resident bootloader to load code into my KL27Z. To reduce the chance of bricking the device, I'm using CRC on the image. Consequently, I want to pad the image with 0xff so the checksum calculation will always be accurate.

Following Erich Styger's excellent blog post, I added the following to my MKL27Z64xxx4_flash.ld file (new code in bold face):

.fini_array :
{
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
} > m_text

.filler :
{
    FILL(0x5A); /* for testing. replace with 0xFF for production */
    . = ORIGIN(m_text) + LENGTH(m_text) - 1;
    BYTE(0xFF);
} > m_text

__etext = .;    /* define a global symbol at end of code */
__DATA_ROM = .; /* Symbol is used by startup for data initialization */

My goal with this is to fill up all unused FLASH with a 0x5A pattern, and at the very last byte write 0xFF. But when I link using this code, I get the error:

Invoking: Cross ARM GNU C++ Linker
arm-none-eabi-g++ -mcpu=cortex-m0plus -mthumb -Og -fmessage-length=0 -fsigned-char ...
arm-none-eabi/bin/ld: region m_text overflowed with text and data
collect2: error: ld returned 1 exit status

I should mention that when I comment out the .filler {} section, the link process completes without error, and has ample room to spare:

Invoking: Cross ARM GNU Print Size
arm-none-eabi-size --format=berkeley "rex.elf"
text data bss dec hex filename
37532 2404 3216 43152 a890 rex.elf
Finished building: rex.siz
Finished building: rex.srec

Any idea what's going on?

Re: Padding FLASH without overflowing memory

BlackNight — Mon, 02 Nov 2020 14:14:19 GMT

Hi Robert,

thanks for the flowers :-).

The error might be produced by something else you have in your linker file. I have below a linker file which works for me. Maybe you can compare it with what you have?

/*
** ###################################################################
**     Processors:          MKL25Z128VFM4
**                          MKL25Z128VFT4
**                          MKL25Z128VLH4
**                          MKL25Z128VLK4
**
**     Compiler:            GNU C Compiler
**     Reference manual:    KL25P80M48SF0RM, Rev.3, Sep 2012
**     Version:             rev. 2.5, 2015-02-19
**     Build:               b150220
**
**     Abstract:
**         Linker file for the GNU C Compiler
**
**     Copyright (c) 2015 Freescale Semiconductor, Inc.
**     All rights reserved.
**
**     Redistribution and use in source and binary forms, with or without modification,
**     are permitted provided that the following conditions are met:
**
**     o Redistributions of source code must retain the above copyright notice, this list
**       of conditions and the following disclaimer.
**
**     o Redistributions in binary form must reproduce the above copyright notice, this
**       list of conditions and the following disclaimer in the documentation and/or
**       other materials provided with the distribution.
**
**     o Neither the name of Freescale Semiconductor, Inc. nor the names of its
**       contributors may be used to endorse or promote products derived from this
**       software without specific prior written permission.
**
**     THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
**     ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
**     WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
**     DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
**     ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
**     (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
**     LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
**     ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
**     (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
**     SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
**
**     http:                 www.freescale.com
**     mail:                 support@freescale.com
**
** ###################################################################
*/

/* Entry Point */
ENTRY(Reset_Handler)

HEAP_SIZE  = DEFINED(__heap_size__)  ? __heap_size__  : 0x0400;
STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0400;

/* Specify the memory areas */
MEMORY
{
  m_interrupts          (RX)  : ORIGIN = 0x00000000, LENGTH = 0x00000100
  m_flash_config        (RX)  : ORIGIN = 0x00000400, LENGTH = 0x00000010
  m_text                (RX)  : ORIGIN = 0x00000410, LENGTH = 0x0001FBF0
  m_data                (RW)  : ORIGIN = 0x1FFFF000, LENGTH = 0x00004000
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into internal flash */
  .interrupts :
  {
    __VECTOR_TABLE = .;
    . = ALIGN(4);
    KEEP(*(.isr_vector))     /* Startup code */
    . = ALIGN(4);
  } > m_interrupts

  .flash_config :
  {
    . = ALIGN(4);
    KEEP(*(.FlashConfig))    /* Flash Configuration Field (FCF) */
    . = ALIGN(4);
  } > m_flash_config

  /* The program code and other data goes into internal flash */
  .text :
  {
    . = ALIGN(4);
    *(.text)                 /* .text sections (code) */
    *(.text*)                /* .text* sections (code) */
    *(.rodata)               /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)              /* .rodata* sections (constants, strings, etc.) */
    *(.glue_7)               /* glue arm to thumb code */
    *(.glue_7t)              /* glue thumb to arm code */
    *(.eh_frame)
    KEEP (*(.init))
    KEEP (*(.fini))
    . = ALIGN(4);
  } > m_text

  .ARM.extab :
  {
    *(.ARM.extab* .gnu.linkonce.armextab.*)
  } > m_text

  .ARM :
  {
    __exidx_start = .;
    *(.ARM.exidx*)
    __exidx_end = .;
  } > m_text

 .ctors :
  {
    __CTOR_LIST__ = .;
    /* gcc uses crtbegin.o to find the start of
       the constructors, so we make sure it is
       first.  Because this is a wildcard, it
       doesn't matter if the user does not
       actually link against crtbegin.o; the
       linker won't look for a file to match a
       wildcard.  The wildcard also means that it
       doesn't matter which directory crtbegin.o
       is in.  */
    KEEP (*crtbegin.o(.ctors))
    KEEP (*crtbegin?.o(.ctors))
    /* We don't want to include the .ctor section from
       from the crtend.o file until after the sorted ctors.
       The .ctor section from the crtend file contains the
       end of ctors marker and it must be last */
    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
    KEEP (*(SORT(.ctors.*)))
    KEEP (*(.ctors))
    __CTOR_END__ = .;
  } > m_text

  .dtors :
  {
    __DTOR_LIST__ = .;
    KEEP (*crtbegin.o(.dtors))
    KEEP (*crtbegin?.o(.dtors))
    KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
    KEEP (*(SORT(.dtors.*)))
    KEEP (*(.dtors))
    __DTOR_END__ = .;
  } > m_text

  .preinit_array :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } > m_text

  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } > m_text

  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(SORT(.fini_array.*)))
    KEEP (*(.fini_array*))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } > m_text

.filler :
  {
    FILL(0x5A);  /* for testing.  replace with 0xFF for production */
    . = ORIGIN(m_text) + LENGTH(m_text) - 1;
    BYTE(0xFF);
  } > m_text

  __etext = .;    /* define a global symbol at end of code */
  __DATA_ROM = .; /* Symbol is used by startup for data initialization */

  /* reserve MTB memory at the beginning of m_data */
  .mtb : /* MTB buffer address as defined by the hardware */
  {
    . = ALIGN(8);
    _mtb_start = .;
    KEEP(*(.mtb_buf)) /* need to KEEP Micro Trace Buffer as not referenced by application */
    . = ALIGN(8);
    _mtb_end = .;
  } > m_data

  .data : AT(__DATA_ROM)
  {
    . = ALIGN(4);
    __DATA_RAM = .;
    __data_start__ = .;      /* create a global symbol at data start */
    *(.data)                 /* .data sections */
    *(.data*)                /* .data* sections */
    KEEP(*(.jcr*))
    . = ALIGN(4);
    __data_end__ = .;        /* define a global symbol at data end */
  } > m_data

  __DATA_END = __DATA_ROM + (__data_end__ - __data_start__);

  /* Uninitialized data section */
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss section */
    . = ALIGN(4);
    __START_BSS = .;
    __bss_start__ = .;
    *(.bss)
    *(.bss*)
    *(COMMON)
    . = ALIGN(4);
    __bss_end__ = .;
    __END_BSS = .;
  } > m_data

  .heap :
  {
    . = ALIGN(8);
    __end__ = .;
    PROVIDE(end = .);
    __HeapBase = .;
    . += HEAP_SIZE;
    __HeapLimit = .;
  } > m_data

  .stack :
  {
    . = ALIGN(8);
    . += STACK_SIZE;
  } > m_data

  
  /* Initializes stack on the end of block */
  __StackTop   = ORIGIN(m_data) + LENGTH(m_data);
  __StackLimit = __StackTop - STACK_SIZE;
  PROVIDE(__stack = __StackTop);

  .ARM.attributes 0 : { *(.ARM.attributes) }

  ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
}

‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍‍

I hope this helps,

Erich

Re: Padding FLASH without overflowing memory

Alice_Yang — Thu, 09 Aug 2018 09:49:24 GMT

Hello Erich and Robert,

I also refer to Erich's blog to configed on my side.

I find that if create a SDK project on KDS, there is a bit difference with bare board project,

it increased the blow code :

So there will be the error message Robert mentioned. If delete them , there is no error after build.

While in the srec file , data overflowed:

Alice

Re: Padding FLASH without overflowing memory

BlackNight — Fri, 10 Aug 2018 08:23:26 GMT

Dealing with the GNU linker script can get very tricky with loadable sections.

The thing is that with that linker file there is the ROM init code which is using the AT() section command which moves the 'current cursor'.

I tried to get some kind of solution or hack around this, but that gets very ugly quickly.

What I recommend is using the SRecord tool (SRecord 1.64 ) for this kind of filling.

I hope this helps,

Erich

Re: Padding FLASH without overflowing memory

Alice_Yang — Fri, 10 Aug 2018 08:54:25 GMT

Hello Erich,

Thank you very much for help.

Alice

Re: Padding FLASH without overflowing memory

robertpoor — Mon, 02 Nov 2020 14:14:21 GMT

Erich, Alice:

Thank you both for your comments. I'm attaching my entire .ld file -- it's *very* close to that which Erich tested, at least in the .text section. (There's additional sections for USB RAM, etc, but I don't see how that will affect things.)

But given Alice's feedback and Erich's subsequent suggestion, we should probably file this as a bug and move on. I already use the SRecord tool to calculate and insert the CRC into the Bootloader Control Area of the image, so I might as well use it to pad the resulting file as well.

(I do have a related question about that, but I'll post that as a separate thread.)

Thanks for your help!

- rdp

/*
** ###################################################################
** Processors: MKL27Z64VDA4
** MKL27Z64VFM4
** MKL27Z64VFT4
** MKL27Z64VLH4
** MKL27Z64VMP4
**
** Compiler: GNU C Compiler
** Reference manual: KL27P64M48SF2RM, Rev. 1, Sep 2014
** Version: rev. 1.4, 2014-09-22
** Build: b170214
**
** Abstract:
** Linker file for the GNU C Compiler
**
** Copyright 2016 Freescale Semiconductor, Inc.
** Copyright 2016-2017 NXP
** Redistribution and use in source and binary forms, with or without modification,
** are permitted provided that the following conditions are met:
**
** o Redistributions of source code must retain the above copyright notice, this list
** of conditions and the following disclaimer.
**
** o Redistributions in binary form must reproduce the above copyright notice, this
** list of conditions and the following disclaimer in the documentation and/or
** other materials provided with the distribution.
**
** o Neither the name of the copyright holder nor the names of its
** contributors may be used to endorse or promote products derived from this
** software without specific prior written permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
** ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
** WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
** DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
** ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
** (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
** LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
** ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
** SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
**
** http: www.nxp.com
** mail: support@nxp.com
**
** ###################################################################
*/

/* Entry Point */
ENTRY(Reset_Handler)

HEAP_SIZE = DEFINED(__heap_size__) ? __heap_size__ : 0x0400;
STACK_SIZE = DEFINED(__stack_size__) ? __stack_size__ : 0x0400;
M_VECTOR_RAM_SIZE = DEFINED(__ram_vector_table__) ? 0x0200 : 0x0;

/*
 * To make the app loadable by the Flash Resident Bootloader, we must ensure 
 * that the app gets loaded into memory beyond the end of the bootloader at 
 * CODE_BASE_ADDR. This must match BL_APP_VECTOR_TABLE_ADDRESS defined in 
 * bootloader_config.h in the flash-resident bootloader.
 */
BASE_ADDR = 0x4000;

/* But we can't use BASE_ADDR symbolically. Sigh... */

MEMORY
{
 m_interrupts (RX) : ORIGIN = 0x4000, LENGTH = 0x0200
 m_bootloader_config (RX) : ORIGIN = 0x43C0, LENGTH = 0x0040
 /* code starts at 4400, ends one page before end of flash (for user params) */
 m_text (RX) : ORIGIN = 0x4400, LENGTH = 0x10000 - (0x4400 + 0x400)
 m_data (RW) : ORIGIN = 0x1FFFF000, LENGTH = 0x4000
 m_usb_sram (RW) : ORIGIN = 0x400FE000, LENGTH = 0x0200
}

/* Define output sections */
SECTIONS
{
 /* The startup code goes first into internal flash */
 .interrupts :
 {
 __VECTOR_TABLE = .;
 . = ALIGN(4);
 KEEP(*(.isr_vector)) /* Startup code */
 . = ALIGN(4);
 } > m_interrupts

.bca :
 {
 . = ALIGN(4);
 KEEP(*(.BootloaderConfig)) /* Bootloader Configuration Area (BCA) */
 . = ALIGN(4);
 } > m_bootloader_config

/* The program code and other data goes into internal flash */
 .text :
 {
 . = ALIGN(4);
 *(.text) /* .text sections (code) */
 *(.text*) /* .text* sections (code) */
 *(.rodata) /* .rodata sections (constants, strings, etc.) */
 *(.rodata*) /* .rodata* sections (constants, strings, etc.) */
 *(.glue_7) /* glue arm to thumb code */
 *(.glue_7t) /* glue thumb to arm code */
 *(.eh_frame)
 KEEP (*(.init))
 KEEP (*(.fini))
 . = ALIGN(4);
 } > m_text

.ARM.extab :
 {
 *(.ARM.extab* .gnu.linkonce.armextab.*)
 } > m_text

.ARM :
 {
 __exidx_start = .;
 *(.ARM.exidx*)
 __exidx_end = .;
 } > m_text

.ctors :
 {
 __CTOR_LIST__ = .;
 /* gcc uses crtbegin.o to find the start of
 the constructors, so we make sure it is
 first. Because this is a wildcard, it
 doesn't matter if the user does not
 actually link against crtbegin.o; the
 linker won't look for a file to match a
 wildcard. The wildcard also means that it
 doesn't matter which directory crtbegin.o
 is in. */
 KEEP (*crtbegin.o(.ctors))
 KEEP (*crtbegin?.o(.ctors))
 /* We don't want to include the .ctor section from
 from the crtend.o file until after the sorted ctors.
 The .ctor section from the crtend file contains the
 end of ctors marker and it must be last */
 KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .ctors))
 KEEP (*(SORT(.ctors.*)))
 KEEP (*(.ctors))
 __CTOR_END__ = .;
 } > m_text

.dtors :
 {
 __DTOR_LIST__ = .;
 KEEP (*crtbegin.o(.dtors))
 KEEP (*crtbegin?.o(.dtors))
 KEEP (*(EXCLUDE_FILE(*crtend?.o *crtend.o) .dtors))
 KEEP (*(SORT(.dtors.*)))
 KEEP (*(.dtors))
 __DTOR_END__ = .;
 } > m_text

.preinit_array :
 {
 PROVIDE_HIDDEN (__preinit_array_start = .);
 KEEP (*(.preinit_array*))
 PROVIDE_HIDDEN (__preinit_array_end = .);
 } > m_text

.init_array :
 {
 PROVIDE_HIDDEN (__init_array_start = .);
 KEEP (*(SORT(.init_array.*)))
 KEEP (*(.init_array*))
 PROVIDE_HIDDEN (__init_array_end = .);
 } > m_text

.fini_array :
 {
 PROVIDE_HIDDEN (__fini_array_start = .);
 KEEP (*(SORT(.fini_array.*)))
 KEEP (*(.fini_array*))
 PROVIDE_HIDDEN (__fini_array_end = .);
 } > m_text

/* 
 * Pad flash with 0xff to guarantee checksum calculations.
 * see https://mcuoneclipse.com/2014/06/23/filling-unused-memory-with-the-gnu-linker
 */
 /*
 * Not ready for prime time: https://community.nxp.com/message/1044054
 .filler :
 {
 FILL(0x5A);
 . = ORIGIN(m_text) + LENGTH(m_text) - 1;
 BYTE(0xFF)
 } > m_text
 */
 
 __etext = .; /* define a global symbol at end of code */
 __DATA_ROM = .; /* Symbol is used by startup for data initialization */

/* reserve MTB memory at the beginning of m_data */
 .mtb : /* MTB buffer address as defined by the hardware */
 {
 . = ALIGN(8);
 _mtb_start = .;
 KEEP(*(.mtb_buf)) /* need to KEEP Micro Trace Buffer as not referenced by application */
 . = ALIGN(8);
 _mtb_end = .;
 } > m_data

.interrupts_ram :
 {
 . = ALIGN(4);
 __VECTOR_RAM__ = .;
 __interrupts_ram_start__ = .; /* Create a global symbol at data start */
 *(.m_interrupts_ram) /* This is a user defined section */
 . += M_VECTOR_RAM_SIZE;
 . = ALIGN(4);
 __interrupts_ram_end__ = .; /* Define a global symbol at data end */
 } > m_data

__VECTOR_RAM = DEFINED(__ram_vector_table__) ? __VECTOR_RAM__ : ORIGIN(m_interrupts);
 __RAM_VECTOR_TABLE_SIZE_BYTES = DEFINED(__ram_vector_table__) ? (__interrupts_ram_end__ - __interrupts_ram_start__) : 0x0;

.data : AT(__DATA_ROM)
 {
 . = ALIGN(4);
 __DATA_RAM = .;
 __data_start__ = .; /* create a global symbol at data start */
 *(.data) /* .data sections */
 *(.data*) /* .data* sections */
 KEEP(*(.jcr*))
 . = ALIGN(4);
 __data_end__ = .; /* define a global symbol at data end */
 } > m_data

__DATA_END = __DATA_ROM + (__data_end__ - __data_start__);
 text_end = ORIGIN(m_text) + LENGTH(m_text);
 ASSERT(__DATA_END <= text_end, "region m_text overflowed with text and data")

/* Uninitialized data section */
 .bss :
 {
 /* This is used by the startup in order to initialize the .bss section */
 . = ALIGN(4);
 __START_BSS = .;
 __bss_start__ = .;
 *(.bss)
 *(.bss*)
 *(m_usb_global)
 *(COMMON)
 . = ALIGN(4);
 __bss_end__ = .;
 __END_BSS = .;
 } > m_data

.heap :
 {
 . = ALIGN(8);
 __end__ = .;
 PROVIDE(end = .);
 __HeapBase = .;
 . += HEAP_SIZE;
 __HeapLimit = .;
 __heap_limit = .; /* Add for _sbrk */
 } > m_data

.stack :
 {
 . = ALIGN(8);
 . += STACK_SIZE;
 } > m_data

m_usb_bdt (NOLOAD) :
 {
 . = ALIGN(512);
 *(m_usb_bdt)
 } > m_usb_sram


 /* Initializes stack on the end of block */
 __StackTop = ORIGIN(m_data) + LENGTH(m_data);
 __StackLimit = __StackTop - STACK_SIZE;
 PROVIDE(__stack = __StackTop);

.ARM.attributes 0 : { *(.ARM.attributes) }

ASSERT(__StackLimit >= __HeapLimit, "region m_data overflowed with stack and heap")
}